Hcfyk

I was unsure as to how to integrate an absolute function, such as $int_0^3 left|sqrt{9-x^2}right|dx$, so I tried:

Integrate[Abs[(9-x^2)^(1/2)],x]

But it returned:

$int sqrt{Abs[9-x^2]}mathbb{d}x$

Could someone please show me how to do so correctly? And also, is there a way of evaluating the integral without having to make it a function and sub in the values of the terminals?

Use RealAbs

Integrate[RealAbs[(9 - x^2)^(1/2)], x]

Use Assumptions:

Integrate[Abs[(9 - x^2)^(1/2)], x, Assumptions -> x [Element] Reals]

Differences[% /. {{x -> 0}, {x -> 3}}]

Explanation of the math: Mathematica defaults to complex analysis, but many users I suspect tend to think in terms of real-variable calculus, often just in terms of single-variable calculus on problems like the OP's. Unlike the real absolute value, the complex absolute value does not have an antiderivative. More particularly, integrals of (continuous) functions of the real absolute value are "path independent"¹⁾: that is, there is a "potential function" F[x] such that the integral from a to b is given by the values of at the end points F[b] - F[a], and the values of F[x] along the path from a to b do not matter. For integrals on the 1D real line, the potential function is the same as the antiderivative. However, integrals over paths in the complex plane of functions of the complex absolute value Abs are generally not path independent. Hence there cannot be a potential function that can be used to evaluate the integral by subtracting values at the end points. Here's a numerical example, in which the end points of the paths are the same but the values of the integrals are not (Integrate and NIntegrate use straight-lined paths through the complex numbers specified):

NIntegrate[Abs[(9 - x^2)^(1/2)], {x, 0, 3}]

(*  7.06858  *)



NIntegrate[Abs[(9 - x^2)^(1/2)], {x, 0, 2 + 2 I, 3}]

(*  8.55748 + 1.50584 I  *)

Consequently, the answer to the OP's integral,

Integrate[Abs[(9 - x^2)^(1/2)], x]

does not exist.

¹⁾ Note: I'm borrowing the terms "path independent" and "potential function" from vector calculus. They are usually only introduced in dimension 2 and higher, because dimension 1 may be understood in simpler terms in first-year calculus. In a comparison of complex analysis with single-variable real calculus, it is natural to consider the real integral $int_a^b f(x) , dx$ as a path integral in the complex plane whose path happens to lie on the real axis. It is also valid to consider it a path integral of a 1D vector field on the 1D real line.

Integrate's variable declaration can be either a variable by itself, as you currently have it (x), or as a variable with its endpoints. The latter form will evaluate in full automatically:

Integrate[Abs[(9 - x^2)^(1/2)], {x, 0, 3}]

$frac{9pi}{4}$

This is the second usage shown in Integrate's documentation, so please check there if you have any further questions on it.

In general, the indefinite integrals of functions containing an absolute value are messier than strictly necessary. However, if you specify appropriate assumptions (particularly that x is real), Mathematica can divide it into a piecewise function:

Integrate[Abs[(9 - x^2)^(1/2)], x, Assumptions -> {x [Element] Reals}]

The result is a mess, so I'd recommend looking at it on your own machine. If complex values are allowed, then ComplexExpand would ordinarily be helpful.

Integrate[ComplexExpand[Abs[(9 - x^2)^(1/2)], x], x]

In this case, however, it just returns a different, more complicated looking integral.

For indefinite integrals replace Abs by the square root of the square:

Integrate[Sqrt[((9 - x^2)^(1/2))^2], x]

(* 1/2 x Sqrt[9 - x^2] + 9/2 ArcSin[x/3] *)